OpenAIのChatGPTのAPIを呼び出すAPEXアプリを作る
作成したアプリケーションは以下のように動作します。
関数呼び出しが行われた場合（Chat HistoryのタイプでfunctionResponseが現れた場合）関数呼び出しの戻り値をGeminiに渡すため、Textを空白にしてRunをクリックする必要があります。
クイックSQLの以下のモデルより、表GEMINI_FUNCTIONSを作成します。
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
| # prefix: gemini | |
| functions | |
| function_name vc200 /nn | |
| function_set_name vc20 /nn | |
| description vc4000 /nn | |
| parameters json /nn |
この表はOpenAIでの作業の際に作成した表OPENAI_FUNCTIONSとOPENAI_FUNCTION_SETを（不具合の修正も合わせて）簡素にしています。この表にサンプルとして設定するファンクションとして、OpenAIのときと同じget_current_weatherを使用します。
表を作成した後、この表にデータを投入するためにフォーム付き対話モード・レポートのページを作成します。
ページの作成をクリックします。
対話モード・レポートを選択します。
対話モード・レポートのページのページ名はFunctionsとします。フォーム・ページを含めるをチェックします。フォーム・ページ名はFunction Detailとします。
データ・ソースの表/ビューの名前にGEMINI_FUNCTIONSを指定します。
次へ進み、主キー列1にID (Number)を選択しページの作成をクリックすると、表GEMINI_FUNCTIONSの対話モード・レポートとフォームのページが作成されます。
ファンクションGET_CURRENT_WEATHERも作成しておきます。元記事に説明がありますが、このファンクションは引数である都市名から座標を得るために、アマノ技研さんより提供されている「世界の百万都市の位置データ Location Data of Megacities」のCSVファイルを表AMANO_CITY_LOCATIONSにロードしています。
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
| create or replace function get_current_weather( | |
| p_args in clob | |
| ) | |
| return clob | |
| as | |
| l_args json_object_t; | |
| l_location varchar2(400); | |
| l_location_tokens apex_t_varchar2; | |
| l_lat number; | |
| l_lon number; | |
| l_url varchar2(4000); | |
| l_response clob; | |
| l_response_json json_object_t; | |
| l_weathercode number; | |
| l_weather varchar2(4000); | |
| begin | |
| l_args := json_object_t(p_args); | |
| l_location := l_args.get_string('location'); | |
| /* get first part (city name) from the location */ | |
| l_location_tokens := apex_string.split(l_location, '[ ,]'); | |
| l_location := l_location_tokens(1); | |
| /* | |
| * 都市名から緯度経度の情報を取り出す。 | |
| * アマノ技研さんより提供されている「世界の百万都市の位置データ Location Data of Megacities」の | |
| * CSVファイルを表AMANO_CITY_LOCATIONSにロードしています。 | |
| * 参照: https://amano-tec.com/data/megacities.html | |
| */ | |
| select lat, lon into l_lat, l_lon | |
| from amano_city_locations | |
| where upper(capital_en) = upper(l_location) or capital_jp = l_location; | |
| /* | |
| * Open-Meteo.comのAPIを呼び出し、指定した座標の現在の天気を取得しています。 | |
| * 参照: https://open-meteo.com | |
| */ | |
| l_url := 'https://api.open-meteo.com/v1/forecast?latitude=' || l_lat || '&longitude=' || l_lon || '¤t=weathercode'; | |
| l_response := apex_web_service.make_rest_request( | |
| p_url => l_url | |
| ,p_http_method => 'GET' | |
| ); | |
| if apex_web_service.g_status_code <> 200 then | |
| return '{ "error": "open-meteo.com api call failed, response = ' || l_response || '" }'; | |
| end if; | |
| l_response_json := json_object_t(l_response); | |
| /* | |
| * Weather Code (WMO 4501)のコードの説明は以下の気象関係コード表のWMO 4501の部分を | |
| * 表WMO4501として読み込んでいます。 | |
| * 参照: https://www.jodc.go.jp/data_format/weather-code_j.html | |
| */ | |
| l_weathercode := l_response_json.get_object('current').get_number('weathercode'); | |
| select description into l_weather from wmo4501 where code = l_weathercode; | |
| return '{ "weather" : "' || l_weather || '" }'; | |
| exception | |
| when no_data_found then | |
| return '{ "error": "no data found" }'; | |
| end get_current_weather; | |
| / |
アプリケーションを実行しFunctionsのページを開き、作成をクリックします。
ファンクションGET_CURRENT_WEATHERを登録します。
Function nameとしてget_current_weather、Function Set NameとしてWeather、DescriptionとしてGet the current weather in a given location、Parametersには以下のJSONドキュメントを記述します。
{
"type": "object",
"properties": {
"location": {
"type": "string",
"description": "The city name"
},
"unit": {
"type": "string",
"enum": [
"celsius",
"fahrenheit"
]
}
},
"required": [
"location"
]
}作成をクリックします。
ファンクションget_current_weatherが設定されます。
APEXアプリケーションへマルチターンの処理を行うページを追加します。
ページの作成をクリックします。
空白のページを選択します。
ページ番号は６、ページの名前はChatとします。
ページの作成をクリックします。
空白のページが作成されます。
会話を初期化するボタンINIT_CONVERSATIONを作成します。ラベルはInitialize Conversation、動作のアクションはデフォルトのページの送信です。テンプレート・オプションのWidthをStretchに変更しています。
作成したプロセスの識別の名前をInitialize Conversationとします。タイプはコードを実行です。ソースのPL/SQLコードに以下を記述します。チャット履歴を保持するAPEXコレクションGEMINIを初期化しています。
apex_collection.create_or_truncate_collection(
p_collection_name => 'GEMINI'
);サーバー側の条件のボタン押下時にINIT_CONVERSATIONを指定します。
レンダリング・ビューに戻ります。
テキストを入力するページ・アイテムP6_TEXTを作成します。タイプはテキスト領域、ラベルはTextとします。
セッション・ステートのデータ型にCLOBを選択し、続けて同じテキストを送信してしまわないように、ストレージとしてリクエストごと(メモリーのみ)を選択します。
ファンクション・セットを選択するページ・アイテムP6_FUNCTION_SETを作成します。
タイプは選択リスト、ラベルはFunction Setとします。LOVのタイプにSQL問合せを選択し、SQL問合せとして以下を記述します。
select function_set_name d, function_set_name r from gemini_functions group by function_set_name order by 1 asc追加値の表示はオフ、NULL値の表示をオンとし、NULL表示値として- ファンクション・セットを選択 -と記述します。
セッション・ステートのストレージはセッションごと(永続)を選択します。
会話を実行するボタンRUNを作成します。ラベルはRun、動作のアクションはデフォルトのページの送信です。外観のホットをオンにします。テンプレート・オプションのWidthをStretchに変更しています。
プロセス・ビューを開き、このボタンRUNがクリックされたときに実行されるプロセスを作成します。
作成したプロセスの識別の名前をRun Conversationとします。タイプはコードを実行です。ソースのPL/SQLコードに以下を記述します。
This file contains bidirectional Unicode text that may be interpreted or compiled differently than what appears below. To review, open the file in an editor that reveals hidden Unicode characters.
Learn more about bidirectional Unicode characters
| declare | |
| l_user_text clob := :P6_TEXT; | |
| l_functioin_set_name varchar2(40) := :P6_FUNCTION_SET; | |
| -- | |
| l_contents json_array_t := json_array_t(); | |
| l_contents_clob clob; | |
| l_content json_object_t; | |
| l_parts json_array_t; | |
| l_part json_object_t; | |
| -- function calling | |
| l_functions json_array_t; | |
| l_function json_object_t; | |
| l_parameters json_object_t; | |
| l_tools json_array_t; | |
| l_tools_clob clob; | |
| l_tool json_object_t; | |
| -- response | |
| l_candidates json_array_t; | |
| l_prompt_feedback json_object_t; | |
| l_response clob; | |
| l_reply clob; | |
| l_role varchar2(8); | |
| begin | |
| /* | |
| * add user input first. | |
| */ | |
| if l_user_text is not null then | |
| apex_collection.add_member( | |
| p_collection_name => 'GEMINI' | |
| ,p_c001 => 'user' | |
| ,p_c002 => 'text' | |
| ,p_clob001 => l_user_text | |
| ); | |
| end if; | |
| /* | |
| * reconstruct chat history from apex collection. | |
| */ | |
| for r in (select c001, c002, clob001 from apex_collections where collection_name = 'GEMINI' order by seq_id) | |
| loop | |
| l_content := json_object_t(); | |
| l_content.put('role',r.c001); | |
| l_part := json_object_t(); | |
| case r.c002 | |
| when 'text' then | |
| l_part.put('text', r.clob001); | |
| else | |
| l_part.put(r.c002, json_object_t(r.clob001)); | |
| end case; | |
| l_parts := json_array_t(); | |
| l_parts.append(l_part); | |
| l_content.put('parts', l_parts); | |
| l_contents.append(l_content); | |
| end loop; | |
| l_contents_clob := l_contents.to_clob(); | |
| -- prepare tools | |
| if l_functioin_set_name is not null then | |
| l_functions := json_array_t(); | |
| for r in ( | |
| select * from gemini_functions where function_set_name = l_functioin_set_name | |
| ) | |
| loop | |
| l_function := json_object_t(); | |
| l_function.put('name', r.function_name); | |
| l_function.put('description', r.description); | |
| l_parameters := json_object_t(r.parameters); | |
| l_function.put('parameters', l_parameters); | |
| l_functions.append(l_function); | |
| end loop; | |
| l_tool := json_object_t(); | |
| l_tool.put('function_declarations', l_functions); | |
| l_tools := json_array_t(); | |
| l_tools.append(l_tool); | |
| l_tools_clob := l_tools.to_clob(); | |
| else | |
| l_tools_clob := null; | |
| end if; | |
| -- apex_debug.info(l_contents_clob); | |
| utl_google_gemini_api.generate_content( | |
| p_contents => l_contents_clob | |
| ,p_tools => l_tools_clob | |
| ,p_candidates => l_candidates | |
| ,p_prompt_feedback => l_prompt_feedback | |
| ,p_response => l_response | |
| ,p_credential_static_id => :G_CREDENTIAL | |
| ); | |
| apex_debug.info(l_response); | |
| l_part := utl_google_gemini_api.get_first_part( | |
| p_candidates => l_candidates | |
| ,p_role => l_role | |
| ); | |
| l_reply := l_part.get_string('text'); | |
| if l_reply is null then | |
| /* append functionCall to chat history. */ | |
| apex_collection.add_member( | |
| p_collection_name => 'GEMINI' | |
| ,p_c001 => l_role | |
| ,p_c002 => 'functionCall' | |
| ,p_clob001 => l_part.get_object('functionCall').to_clob() | |
| ); | |
| /* call external function */ | |
| l_reply := utl_google_gemini_api.call_function( | |
| p_part => l_part | |
| ); | |
| /* append functionResponse to chat history */ | |
| apex_collection.add_member( | |
| p_collection_name => 'GEMINI' | |
| ,p_c001 => 'function' | |
| ,p_c002 => 'functionResponse' | |
| ,p_clob001 => l_reply | |
| ); | |
| else | |
| apex_collection.add_member( | |
| p_collection_name => 'GEMINI' | |
| ,p_c001 => l_role | |
| ,p_c002 => 'text' | |
| ,p_clob001 => l_reply | |
| ); | |
| end if; | |
| end; |
サーバー側の条件のボタン押下時にRUNを指定します。
レンダリング・ツリーに戻り、チャット履歴を表示するクラシック・レポートのリージョンを作成します。
識別のタイトルはChat History、ソースのタイプとしてSQL問合せを選択し、SQL問合せとして以下を記述します。
select c001, c002, clob001 from apex_collections where collection_name = 'GEMINI' order by seq_id
列C001のヘッダーをroleとします。
列C002のヘッダーをtypeとします。
以上でアプリケーションは完成です。アプリケーションを実行すると、記事の先頭のGIF動画のように動作します。
今回作成したアプリケーションのエクスポートを以下に置きました。
https://github.com/ujnak/apexapps/blob/master/exports/google-gemini2.zip
Oracle APEXのアプリケーション作成の参考になれば幸いです。
完
