日日是Oracle APEX: 行政区域データのまとめ

こちらの記事で行政区域データを、行政区域コードや都道府県でまとめる作業を行いました。以下に、追加で確認したことを書き留めておきます。

SDO_UTIL.RECTIFY_GEOMETRYの結果

GeoJSONのデータを表JAR_JAPAN_REGION_ADMINSの列GEOMETRYに取り込んだ後に、SDO_UTIL.RECTIFY_GEOMETRYを実行しています。修正したジオメトリは列GEOM_Rへアップデートしています。

列GEOM_Rを確認すると、ジオメトリのSDO_GTYPEに2003(ポリゴン)だけではなく、2007(マルチポリゴン)も含まれています。確認に使用したコードは以下です。

set serveroutput on
declare
    l_geom sdo_geometry;
    l_elem_cnt number;
begin
    for c in (
        select * from jar_japan_region_admins
        where geom_r is not null order by id
    )
    loop
        l_geom := c.geom_r;
        l_elem_cnt := sdo_util.getnumelem(l_geom);
        if l_geom.sdo_gtype <> 2003 then
            dbms_output.put_line('id ' || c.id || ' is ' || l_geom.sdo_gtype || ', contains '
                || l_elem_cnt || ' elements.');
        end if;
    end loop;
end;
/

実行結果は以下のようになりました。

id 922 is 2007, contains 2 elements.

id 67318 is 2007, contains 2 elements.

id 78966 is 2007, contains 2 elements.

id 83266 is 2007, contains 2 elements.

id 94185 is 2007, contains 2 elements.

id 99633 is 2007, contains 2 elements.

id 100483 is 2007, contains 2 elements.

id 100866 is 2007, contains 2 elements.

id 101181 is 2007, contains 2 elements.

このままSDO_UTIL.SIMPLIFYを実行すると、含まれているポリゴンが非常に小さい場合、そのポリゴンが点または線のジオメトリに変換されます。結果としてOracle APEXのマップ・リージョンで表示されないジオメトリになります。

マルチポリゴンのジオメトリを分解し、別のIDを割り振って保存します。実行には以下のコードを使いました。

set serveroutput on
declare
    l_geom sdo_geometry;
    l_elem_cnt number;
    l_geom_in sdo_geometry;
    l_max number;
begin
    for c in (
        select * from jar_japan_region_admins
        where geom_r is not null order by id
    )
    loop
        -- rectifyされたジオメトリが処理の対象。
        l_geom := c.geom_r;
        --
        if l_geom.sdo_gtype in (2004,2007) then
            -- コレクション(2004)とマルチポリゴンが(2007)が修正の対象。
            dbms_output.put_line('id ' || c.id 
                || ' was converted into collection(2004) or multipolygon(2007). try to fix.');
            l_elem_cnt := sdo_util.getnumelem(l_geom);
            select max(id) into l_max from jar_japan_region_admins;
            for i in 1..l_elem_cnt
            loop
                l_geom_in := sdo_util.extract(l_geom,i);
                if l_geom_in.sdo_gtype = 2003 then
                    -- 含まれているポリゴンを新たなIDで追加する。
                    dbms_output.put_line('store inner polygon with new id ' || (l_max+i));
                    insert into jar_japan_region_admins(
                        id, prefecture_name, branch_in_hokkaido, major_city,
                        city_name, admin_code, geom_r, vertices)
                    values(
                        l_max+i, c.prefecture_name, c.branch_in_hokkaido, c.major_city,
                        c.city_name, c.admin_code, l_geom_in, sdo_util.getnumvertices(l_geom_in));
                else
                    -- それ以外は削除される。
                    dbms_output.put_line('ignore inner geometry. ' || l_geom_in.sdo_gtype);
                end if;
            end loop;
            -- 元々のジオメトリは重複したデータになるためNULLにする。
            dbms_output.put_line('nullify original rectified geometry.');
            update jar_japan_region_admins set geom_r = null, vertices = null  where id = c.id;
        end if;
    end loop;
end;
/
commit;

実行結果は以下のようになりました。

id 922 was converted into collection(2004) or multipolygon(2007). try to fix.

store inner polygon with new id 121159

store inner polygon with new id 121160